home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / FLEX.TYPE.SHK / FLEX.TYPE / TURN SIDEWAYS.bas < prev    next >
BASIC Source File  |  2000-01-01  |  2KB  |  59 lines
  1. 10  REM TURN SIDEWAYS
  2. 20  LOMEM: ( PEEK(176) +4) *256
  3. 30  TEXT : HOME 
  4. 40  HTAB 16: INVERSE : PRINT ":SIDEWAYS:": POKE 34,2: NORMAL 
  5. 50  PRINT 
  6. 60  PRINT "DO YOU NEED A DESCRIPTION (Y/N)? ";: GET X$
  7. 70  IF X$ < >"Y"  THEN 120
  8. 80  PRINT : PRINT 
  9. 90  PRINT "THIS PROGRAM WILL TURN ALL OF THE": PRINT "CHARACTERS OF THE SPECIFIED TEXT FONT": PRINT "CLOCKWISE OR COUNTER CLOCKWISE (90 DEG)."
  10. 100  PRINT "(NOTE: THIS IS ONLY RECOMMENDED FOR THE": PRINT "STANDARD 40 COLUMN CHARACTER SETS.)"
  11. 110  PRINT : PRINT "PRESS ANY KEY TO CONTINUE.";: GET X$
  12. 120  HOME 
  13. 130  PRINT "ENTER THE NAME OF THE CHARACTER SET YOU": PRINT "WOULD LIKE TO TURN:": INPUT "";CS$
  14. 140 A = ( PEEK(176) +1) *256
  15. 150  PRINT 
  16. 160  PRINT "LOADING THE CHARACTER SET.": PRINT  CHR$(4)"BLOAD"CS$",A"A
  17. 170  PRINT : PRINT "TURN IT COUNTER CLOCKWISE OR CLOCKWISE": PRINT "( <- OR -> )? ";: GET X$
  18. 180  IF X$ =  CHR$(8)  THEN  PRINT "<-": GOTO 210
  19. 190  IF X$ =  CHR$(21)  THEN  PRINT "->": GOTO 370
  20. 200  VTAB 8: HTAB 1: GOTO 170
  21. 210  PRINT : PRINT "TURNING."
  22. 220  PRINT : PRINT "[  ] <-- THIS WILL BE 96 WHEN DONE.";
  23. 230  FOR I = A TO A +767  STEP 8
  24. 240  FOR J = 0 TO 7:TEMP(J) = 0: NEXT 
  25. 250 P1 = 1
  26. 260  FOR J = 0 TO 6
  27. 270 BYTE =  PEEK(I +J)
  28. 280 P2 = 64
  29. 290  IF BYTE > = 128  THEN BYTE = BYTE -128
  30. 300  FOR K = 6 TO 0  STEP  -1
  31. 310  IF BYTE > = P2  THEN BYTE = BYTE -P2:TEMP(K) = TEMP(K) +P1
  32. 320 P2 = P2/2
  33. 330  NEXT :P1 = P1 *2: NEXT 
  34. 340  FOR J = 0 TO 7: POKE I +(7 -J),TEMP(J): NEXT 
  35. 350  HTAB 2: PRINT  INT((I -A)/8) +1;
  36. 360  NEXT : GOTO 530
  37. 370  PRINT : PRINT "TURNING."
  38. 380  PRINT : PRINT "[  ] <-- THIS WILL BE 96 WHEN DONE.";
  39. 390  FOR I = A TO A +767  STEP 8
  40. 400  FOR J = 0 TO 7:TEMP(J) = 0: NEXT 
  41. 410 P1 = 64
  42. 420  FOR J = 0 TO 6
  43. 430 BYTE =  PEEK(I +J)
  44. 440 P2 = 64
  45. 450  IF BYTE > = 128  THEN BYTE = BYTE -128
  46. 460  FOR K = 6 TO 0  STEP  -1
  47. 470  IF BYTE > = P2  THEN BYTE = BYTE -P2:TEMP(K) = TEMP(K) +P1
  48. 480 P2 = P2/2
  49. 490  NEXT :P1 = P1/2: NEXT 
  50. 500  FOR J = 0 TO 7: POKE I +J,TEMP(J): NEXT 
  51. 510  HTAB 2: PRINT  INT((I -A)/8) +1;
  52. 520  NEXT 
  53. 530  PRINT : PRINT : PRINT "ENTER THE NEW NAME FOR SAVING THE": PRINT "CHARACTER SET. (RETURN FOR SAME NAME)": INPUT "";X$
  54. 540  IF X$ = ""  THEN X$ = CS$
  55. 550  PRINT : PRINT "SAVING THE CHARACTER SET."
  56. 560  PRINT  CHR$(4)"BSAVE"X$",A"A",L"768
  57. 570  PRINT : PRINT "WOULD YOU LIKE TO TURN ANOTHER ": PRINT "CHARACTER SET (Y/N)? ";: GET X$
  58. 580  IF X$ = "Y"  THEN 120
  59. 590  TEXT : HOME : END